{
  description = "Dekker1's home manager configuation";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-24.11-darwin";
    home-manager = {
      url = "github:nix-community/home-manager/release-24.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    darwin = {
      url = "github:LnL7/nix-darwin/nix-darwin-24.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs =
    { darwin
    , home-manager
    , nixpkgs
    , ...
    } @ inputs:
    let
    	# Systems that can be used
      linuxSystems = [ "x86_64-linux" "aarch64-linux" ];
      darwinSystems = [ "aarch64-darwin" "x86_64-darwin" ];
      # Arguments that are passed into the system configuration
      name = "Jip J. Dekker";
      email = "jip@dekker.one";
      sshSignKey = "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIMCC0liW47USr/Ic1rJ52V4eE07y42VG9Ols1zYBrPlc";
      user = "dekker1";
      # Special arguments that are passed into each system configuration
      specialArgs = inputs // { inherit email name sshSignKey user; };
    in
    {
      darwinConfigurations = nixpkgs.lib.genAttrs darwinSystems (system:
	      darwin.lib.darwinSystem {
	        inherit system specialArgs;
	        modules = [
	          home-manager.darwinModules.home-manager
	          ./darwin
	        ];
	      }
      );
      nixosConfigurations = nixpkgs.lib.genAttrs linuxSystems (system: nixpkgs.lib.nixosSystem {
        inherit system specialArgs;
        modules = [
          home-manager.nixosModules.home-manager {
            home-manager = {
              useGlobalPkgs = true;
              useUserPackages = true;
              users.${user} = import ./nixos/home-manager.nix;
            };
          }
          ./nixos
        ];
      });
    };
}