{ config, pkgs, lib, home-manager, ... }:

let
  user = "dekker1";
  sharedFiles = import ../shared/files.nix { inherit config pkgs; };
  additionalFiles = import ./files.nix { inherit user config pkgs; };
in
{
  # It me
  users.users.${user} = {
    name = "${user}";
    home = "/Users/${user}";
    isHidden = false;
    shell = pkgs.zsh;
  };

  homebrew = {
    enable = true;
    onActivation = {
      upgrade = true;
      cleanup = "zap";
    };
    casks = pkgs.callPackage ./casks.nix { };
    brews = [
      "openssl" # Required by cargo-update (`LDFLAGS="-L/usr/local/opt/openssl@3/lib" CPPFLAGS="-I/usr/local/opt/openssl@3/include" cargo install cargo-update`)
      "scip"
    ];
    taps = builtins.attrNames config.nix-homebrew.taps;
  };

  # These app IDs are from using the mas CLI app
  # mas = mac app store
  # https://github.com/mas-cli/mas
  #
  # $ nix shell nixpkgs#mas
  # $ mas search <app name>
  #
  homebrew.masApps = {
    "1Password for Safari" = 1569813296;
    "Baking Soda" = 1601151613;
    "Keynote" = 409183694;
    "Microsoft Excel" = 462058435;
    "Microsoft Word" = 462054704;
    "Numbers" = 409203825;
    "Pages" = 409201541;
    "Pixelmator Pro" = 1289583905;
    "Qantas" = 1468230799;
    "Textual IRC Client" = 1262957439;
    "The Unarchiver" = 425424353;
    "Userscripts-Mac-App" = 1463298887;
    "Vinegar" = 1591303229;
    "Wipr" = 1320666476;
  };

  # Enable home-manager
  home-manager = {
    useGlobalPkgs = true;
    users.${user} = { pkgs, config, lib, ... }: {
      home.enableNixpkgsReleaseCheck = false;
      home.packages = pkgs.callPackage ./packages.nix { };
      home.file = lib.mkMerge [
        sharedFiles
        additionalFiles
      ];
      home.stateVersion = "21.11";
      programs = {
        skim.enable = true;

        ssh.matchBlocks = {
          "*" = {
            extraOptions = {
              "UseKeychain" = "yes";
            };
          };
        };
      } // import ../shared/home-manager.nix {
        inherit config pkgs lib;
      };
    };
  };
}