Jip J. Dekker
2c8ad0004a
93be33a6c2 Add complete predicate REVERT: 4f10c82056 Merge branch 'MiniZinc:master' into feature/on_restart REVERT: 0848ce7ec7 Add changelog for 2.5.5 REVERT: 44e2f770d5 Add test for insertion of ArrayLits into CSE REVERT: 8a68d3dea8 Don't insert par expressions into CSE map unless they're an ArrayLit REVERT: 6bf6f1180f Increase version number of development build REVERT: dcaac92a74 Make min/max on array of opt vars return non-optional var. This is consistent with other functions on optional arrays like sum, product, exists, forall. REVERT: 32aa288884 Update changelog REVERT: a4edf0669f Fix flattening of all-par set literals REVERT: 8c1c9605f6 Fix chain compressor, needs to ignore par constants REVERT: 0cad1c6306 Use file_path on include paths to ensure separator consistency REVERT: 05ad7d1931 Update changelog REVERT: 22f5e2557b Define HAVE_CONFIG_H only for UNIX REVERT: 81c7778d55 Define HAVE_CONFIG_H for CBC REVERT: 1f56608e10 mzn-test: don't check symmetry breaking constraints REVERT: 1a9767457e mzn-test: fix parsing %%%mzn-stat: ... output REVERT: a41533fd54 MIP: report CPU time in %%%mzn-stat: solveTime= REVERT: 9d490acd52 Updated docs on OR-Tools v8 installation REVERT: c513f6599f Add changelog for 2.5.4 REVERT: b2eef2772b Follow ids to declarations when flattening par arrays. Fixes #448. REVERT: c5c846d426 Check if result of flattening rhs of a vardecl is par. REVERT: c496052767 Escape strings when pretty printing include items REVERT: 9e379c995e Canonicalise file names before adding include items into "already seen" list REVERT: d5d5d0d88c Use generic flattening inside generators. Fixes #451. REVERT: dc8630a6e9 Small fix to multi-pass library change: use original include path if it is absolute REVERT: 79c6092bd8 Strip library paths from includes in multi-pass compilation. Fixes #455. REVERT: 897875d6d7 Compile infinite domains with holes into constraints. Fixes #457. REVERT: b4e700dc67 Don't create copies of global declarations when creating par versions of functions REVERT: 0e8cc42bb1 Fix typechecker to coerce bool to int in the objective. REVERT: e05523b344 Add test for dzn output of arrays REVERT: 1e0269000e Don't evaluate output_only arrays when generating dzn output. REVERT: 57018c31d6 Fix matrix transposition in lex2 globals REVERT: 2617c0c829 Fix output variables in lex_chain tests REVERT: ef1a250c98 another efort to fix tests REVERT: c00e199dfd Fix test globals_lex_chain.mzn REVERT: b5c997d045 Fix code analysis REVERT: 3352cf0bd5 SCIP constraint handler for lex_chain_..._orbitope REVERT: 4e71a2cc97 Globals lex_chain_..., including lex_chain_..._orbitope REVERT: d807428baf Move test specifcation into the correct folder REVERT: 5be74bc74d MIP decompositions for lex_less_(bool, int, float) REVERT: 36a554ba40 Don't modify infinte domain of optional variables. Fixes #456. REVERT: f9e5306d75 Run clang-format REVERT: 4b57667608 Fix comment reference to relevant test case REVERT: 648f2ab36d Fix equality of indirection annotations REVERT: ef7be5fd78 MIP decompositions for lex_lesseq_(bool=int, float) REVERT: 6511b14e73 Propagate cv flag correctly. REVERT: 6f27ecf1c0 Never insert par expressions into the CSE map. REVERT: 7414f3ca0f Fix cplex id in example configuration REVERT: 7ad7cec506 Update strictly_decreasing with documentation and opt version REVERT: 8029f6e957 Support undefined enums in type checker. REVERT: 79e0f0f546 Revert using mzn_in_symmetry_breaking_constraint() for SCIP's orbisack REVERT: e88efda76c Fix format REVERT: 4802031dc1 Added test mzn_in_symmetry_breaking_constraint() REVERT: e21cc2515a More format fixes 02 ... REVERT: 5bbd67c130 More format fixes... REVERT: d5f9b777ea Format fixes REVERT: 43757a09a0 Remove MIP-specific fzn_less(eq)_bool(_reif).mzn REVERT: c93b5736a3 SCIP: orbisack constraint handler 'fzn_lex_lesseq__orbisack' REVERT: 4516bb4e2c mzn-test.py: add OR-Tools as checker REVERT: e2176f017d Add fix and test for crash with empty enum. REVERT: ac7db35951 Fix documentation bugs. REVERT: 47ba245832 Fix the incorrect renaming of key in model output interface REVERT: 925796ed20 Fail on empty var domains in agenda REVERT: 1ec19d7025 Fix error messages in CMake FindGurobi, FindCPlex REVERT: 6d169475c1 mzn-test.py: Use -i for intermediate solutions REVERT: df2f3e423a Allow coercion of JSON lists to enum definitions REVERT: 2b0b8165e5 Fix clang-tidy errors REVERT: 6597bc1920 Change the CI build image location REVERT: 360c988452 Remove illegal duplicate keys in .gitlab-ci.yml REVERT: 6a5d69c64b Add missing par opt versions of coercion functions REVERT: 63014e3d8f Don't propagate annotations into annotation calls. Avoids infinite recursion. REVERT: 54b19428ab Don't use GRB_INT_PAR_NONCONVEX if it's undefined REVERT: a5bb56c47d Added piecewise_linear for non-continuous intervals git-subtree-dir: software/minizinc git-subtree-split: 93be33a6c254e54be7cd38abb7ebd6a6022f0c46
236 lines
6.5 KiB
MiniZinc
236 lines
6.5 KiB
MiniZinc
% A MiniZinc model
|
||
<model> ::= [ <item> ";" ... ]
|
||
|
||
% Items
|
||
<item> ::= <include-item>
|
||
| <var-decl-item>
|
||
| <enum-item>
|
||
| <assign-item>
|
||
| <constraint-item>
|
||
| <solve-item>
|
||
| <output-item>
|
||
| <predicate-item>
|
||
| <test-item>
|
||
| <function-item>
|
||
| <annotation-item>
|
||
|
||
<ti-expr-and-id> ::= <ti-expr> ":" <ident>
|
||
|
||
% Include items
|
||
<include-item> ::= "include" <string-literal>
|
||
|
||
% Variable declaration items
|
||
<var-decl-item> ::= <ti-expr-and-id> <annotations> [ "=" <expr> ]
|
||
|
||
% Enum items
|
||
<enum-item> ::= "enum" <ident> <annotations> [ "=" <enum-cases-list> ]
|
||
|
||
<enum-cases-list> ::= <enum-cases>
|
||
| <enum-cases-list> "++" <enum-cases>
|
||
|
||
<enum-cases> ::= "{" <ident> "," ... "}"
|
||
| <ident> "(" <ident> ")"
|
||
|
||
% Assign items
|
||
<assign-item> ::= <ident> "=" <expr>
|
||
|
||
% Constraint items
|
||
<constraint-item> ::= "constraint" <string-annotation> <expr>
|
||
|
||
% Solve item
|
||
<solve-item> ::= "solve" <annotations> "satisfy"
|
||
| "solve" <annotations> "minimize" <expr>
|
||
| "solve" <annotations> "maximize" <expr>
|
||
|
||
% Output items
|
||
<output-item> ::= "output" <expr>
|
||
|
||
% Annotation items
|
||
<annotation-item> ::= "annotation" <ident> <params>
|
||
|
||
% Predicate, test and function items
|
||
<predicate-item> ::= "predicate" <operation-item-tail>
|
||
|
||
<test-item> ::= "test" <operation-item-tail>
|
||
|
||
<function-item> ::= "function" <ti-expr> ":" <operation-item-tail>
|
||
|
||
<operation-item-tail> ::= <ident> <params> <annotations> [ "=" <expr> ]
|
||
|
||
<params> ::= [ ( <ti-expr-and-id> "," ... ) ]
|
||
|
||
% Type-inst expressions
|
||
<ti-expr> ::= <base-ti-expr>
|
||
| <array-ti-expr>
|
||
|
||
<base-ti-expr> ::= <var-par> <opt-ti> <set-ti> <base-ti-expr-tail>
|
||
|
||
<var-par> ::= "var" | "par" | ε
|
||
|
||
<opt-ti> ::= "opt" | ε
|
||
|
||
<set-ti> ::= "set" "of" | ε
|
||
|
||
<base-type> ::= "bool"
|
||
| "int"
|
||
| "float"
|
||
| "string"
|
||
|
||
<base-ti-expr-tail> ::= <ident>
|
||
| <base-type>
|
||
| <ti-variable-expr-tail>
|
||
| "ann"
|
||
| { <expr> "," ... }
|
||
| <num-expr> ".." <num-expr>
|
||
|
||
% Type-inst variables
|
||
<ti-variable-expr-tail> ::= $[A-Za-z][A-Za-z0-9_]*
|
||
|
||
% Array type-inst expressions
|
||
<array-ti-expr> ::= "array" [ <ti-expr> "," ... ] "of" <base-ti-expr>
|
||
| "list" "of" <base-ti-expr>
|
||
|
||
% Expressions
|
||
<expr> ::= <expr-atom> <expr-binop-tail>
|
||
|
||
<expr-atom> ::= <expr-atom-head> <expr-atom-tail> <annotations>
|
||
|
||
<expr-binop-tail> ::= [ <bin-op> <expr> ]
|
||
|
||
<expr-atom-head> ::= <builtin-un-op> <expr-atom>
|
||
| "(" <expr> ")"
|
||
| <ident-or-quoted-op>
|
||
| "_"
|
||
| <bool-literal>
|
||
| <int-literal>
|
||
| <float-literal>
|
||
| <string-literal>
|
||
| <set-literal>
|
||
| <set-comp>
|
||
| <array-literal>
|
||
| <array-literal-2d>
|
||
| <array-comp>
|
||
| <ann-literal>
|
||
| <if-then-else-expr>
|
||
| <let-expr>
|
||
| <call-expr>
|
||
| <gen-call-expr>
|
||
|
||
<expr-atom-tail> ::= ε
|
||
| <array-access-tail> <expr-atom-tail>
|
||
|
||
% Numeric expressions
|
||
<num-expr> ::= <num-expr-atom> <num-expr-binop-tail>
|
||
|
||
<num-expr-atom> ::= <num-expr-atom-head> <expr-atom-tail> <annotations>
|
||
|
||
<num-expr-binop-tail> ::= [ <num-bin-op> <num-expr> ]
|
||
|
||
<num-expr-atom-head> ::= <builtin-num-un-op> <num-expr-atom>
|
||
| "(" <num-expr> ")"
|
||
| <ident-or-quoted-op>
|
||
| <int-literal>
|
||
| <float-literal>
|
||
| <if-then-else-expr>
|
||
| <let-expr>
|
||
| <call-expr>
|
||
| <gen-call-expr>
|
||
|
||
% Built-in operators
|
||
<builtin-op> ::= <builtin-bin-op> | <builtin-un-op>
|
||
|
||
<bin-op> ::= <builtin-bin-op> | ‘<ident>‘
|
||
|
||
<builtin-bin-op> ::= "<->" | "->" | "<-" | "\/" | "xor" | "/\" | "<" | ">" | "<=" | ">=" | "==" | "=" | "!="
|
||
| "in" | "subset" | "superset" | "union" | "diff" | "symdiff"
|
||
| ".." | "intersect" | "++" | <builtin-num-bin-op>
|
||
|
||
<builtin-un-op> ::= "not" | <builtin-num-un-op>
|
||
|
||
% Built-in numeric operators
|
||
<num-bin-op> ::= <builtin-num-bin-op> | ‘<ident>‘
|
||
|
||
<builtin-num-bin-op> ::= "+" | "-" | "*" | "/" | "div" | "mod" | "^"
|
||
|
||
<builtin-num-un-op> ::= "+" | "-"
|
||
|
||
% Boolean literals
|
||
<bool-literal> ::= "false" | "true"
|
||
|
||
% Integer literals
|
||
<int-literal> ::= [0-9]+
|
||
| 0x[0-9A-Fa-f]+
|
||
| 0o[0-7]+
|
||
|
||
% Float literals
|
||
<float-literal> ::= [0-9]+"."[0-9]+
|
||
| [0-9]+"."[0-9]+[Ee][-+]?[0-9]+
|
||
| [0-9]+[Ee][-+]?[0-9]+
|
||
| 0[xX]([0-9a-fA-F]*"."[0-9a-fA-F]+|[0-9a-fA-F]+".")([pP][+-]?[0-9]+)
|
||
| (0[xX][0-9a-fA-F]+[pP][+-]?[0-9]+)
|
||
|
||
% String literals
|
||
<string-contents> ::= ([^"\n\] | \[^\n(])*
|
||
|
||
<string-literal> ::= """ <string-contents> """
|
||
| """ <string-contents> "\(" <string-interpolate-tail>
|
||
|
||
<string-interpolate-tail> ::= <expr> ")"<string-contents>"""
|
||
| <expr> ")"<string-contents>"\(" <string-interpolate-tail>
|
||
|
||
% Set literals
|
||
<set-literal> ::= "{" [ <expr> "," ... ] "}"
|
||
|
||
% Set comprehensions
|
||
<set-comp> ::= "{" <expr> "|" <comp-tail> "}"
|
||
|
||
<comp-tail> ::= <generator> [ "where" <expr> ] "," ...
|
||
|
||
<generator> ::= <ident> "," ... "in" <expr>
|
||
|
||
% Array literals
|
||
<array-literal> ::= "[" [ <expr> "," ... ] "]"
|
||
|
||
% 2D Array literals
|
||
<array-literal-2d> ::= "[|" [ (<expr> "," ...) "|" ... ] "|]"
|
||
|
||
% Array comprehensions
|
||
<array-comp> ::= "[" <expr> "|" <comp-tail> "]"
|
||
|
||
% Array access
|
||
<array-access-tail> ::= "[" <expr> "," ... "]"
|
||
|
||
% Annotation literals
|
||
<ann-literal> ::= <ident> [ "(" <expr> "," ... ")" ]
|
||
|
||
% If-then-else expressions
|
||
<if-then-else-expr> ::= "if" <expr> "then" <expr> [ "elseif" <expr> "then" <expr> ]* "else" <expr> "endif"
|
||
|
||
% Call expressions
|
||
<call-expr> ::= <ident-or-quoted-op> [ "(" <expr> "," ... ")" ]
|
||
|
||
% Let expressions
|
||
<let-expr> ::= "let" "{" <let-item> ";" ... "}" "in" <expr>
|
||
|
||
<let-item> ::= <var-decl-item>
|
||
| <constraint-item>
|
||
|
||
% Generator call expressions
|
||
<gen-call-expr> ::= <ident-or-quoted-op> "(" <comp-tail> ")" "(" <expr> ")"
|
||
|
||
% Miscellaneous
|
||
|
||
% Identifiers
|
||
<ident> ::= [A-Za-z][A-Za-z0-9_]* | ’[^’\xa\xd\x0]*’
|
||
|
||
% Identifiers and quoted operators
|
||
<ident-or-quoted-op> ::= <ident>
|
||
| ’<builtin-op>’
|
||
|
||
% Annotations
|
||
<annotations> ::= [ "::" <annotation> ]*
|
||
|
||
<annotation> ::= <expr-atom-head> <expr-atom-tail>
|
||
|
||
<string-annotation> ::= "::" <string-literal>
|